204177f967
NOTRY=True BUG= Review-Url: https://codereview.webrtc.org/2067683002 Cr-Commit-Position: refs/heads/master@{#13144}
116 lines
4.0 KiB
Plaintext
116 lines
4.0 KiB
Plaintext
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCPeerConnectionFactory+Private.h"
|
|
|
|
#include <memory>
|
|
|
|
#import "NSString+StdString.h"
|
|
#import "RTCAVFoundationVideoSource+Private.h"
|
|
#import "RTCAudioTrack+Private.h"
|
|
#import "RTCMediaStream+Private.h"
|
|
#import "RTCPeerConnection+Private.h"
|
|
#import "RTCVideoSource+Private.h"
|
|
#import "RTCVideoTrack+Private.h"
|
|
#import "WebRTC/RTCLogging.h"
|
|
|
|
#include "webrtc/base/checks.h"
|
|
|
|
@implementation RTCPeerConnectionFactory {
|
|
std::unique_ptr<rtc::Thread> _networkThread;
|
|
std::unique_ptr<rtc::Thread> _workerThread;
|
|
std::unique_ptr<rtc::Thread> _signalingThread;
|
|
BOOL _hasStartedRtcEventLog;
|
|
}
|
|
|
|
@synthesize nativeFactory = _nativeFactory;
|
|
|
|
- (instancetype)init {
|
|
if ((self = [super init])) {
|
|
_networkThread = rtc::Thread::CreateWithSocketServer();
|
|
BOOL result = _networkThread->Start();
|
|
NSAssert(result, @"Failed to start network thread.");
|
|
|
|
_workerThread = rtc::Thread::Create();
|
|
result = _workerThread->Start();
|
|
NSAssert(result, @"Failed to start worker thread.");
|
|
|
|
_signalingThread = rtc::Thread::Create();
|
|
result = _signalingThread->Start();
|
|
NSAssert(result, @"Failed to start signaling thread.");
|
|
|
|
_nativeFactory = webrtc::CreatePeerConnectionFactory(
|
|
_networkThread.get(), _workerThread.get(), _signalingThread.get(),
|
|
nullptr, nullptr, nullptr);
|
|
NSAssert(_nativeFactory, @"Failed to initialize PeerConnectionFactory!");
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (BOOL)startRtcEventLogWithFilePath:(NSString *)filePath
|
|
maxSizeInBytes:(int64_t)maxSizeInBytes {
|
|
RTC_DCHECK(filePath.length);
|
|
RTC_DCHECK_GT(maxSizeInBytes, 0);
|
|
RTC_DCHECK(!_hasStartedRtcEventLog);
|
|
if (_hasStartedRtcEventLog) {
|
|
RTCLogError(@"Event logging already started.");
|
|
return NO;
|
|
}
|
|
int fd = open(filePath.UTF8String, O_WRONLY | O_CREAT | O_TRUNC, S_IRUSR | S_IWUSR);
|
|
if (fd < 0) {
|
|
RTCLogError(@"Error opening file: %@. Error: %d", filePath, errno);
|
|
return NO;
|
|
}
|
|
_hasStartedRtcEventLog = _nativeFactory->StartRtcEventLog(fd, maxSizeInBytes);
|
|
return _hasStartedRtcEventLog;
|
|
}
|
|
|
|
- (void)stopRtcEventLog {
|
|
_nativeFactory->StopRtcEventLog();
|
|
_hasStartedRtcEventLog = NO;
|
|
}
|
|
|
|
- (RTCAVFoundationVideoSource *)avFoundationVideoSourceWithConstraints:
|
|
(nullable RTCMediaConstraints *)constraints {
|
|
return [[RTCAVFoundationVideoSource alloc] initWithFactory:self
|
|
constraints:constraints];
|
|
}
|
|
|
|
- (RTCAudioTrack *)audioTrackWithTrackId:(NSString *)trackId {
|
|
return [[RTCAudioTrack alloc] initWithFactory:self
|
|
trackId:trackId];
|
|
}
|
|
|
|
- (RTCVideoTrack *)videoTrackWithSource:(RTCVideoSource *)source
|
|
trackId:(NSString *)trackId {
|
|
return [[RTCVideoTrack alloc] initWithFactory:self
|
|
source:source
|
|
trackId:trackId];
|
|
}
|
|
|
|
- (RTCMediaStream *)mediaStreamWithStreamId:(NSString *)streamId {
|
|
return [[RTCMediaStream alloc] initWithFactory:self
|
|
streamId:streamId];
|
|
}
|
|
|
|
- (RTCPeerConnection *)peerConnectionWithConfiguration:
|
|
(RTCConfiguration *)configuration
|
|
constraints:
|
|
(RTCMediaConstraints *)constraints
|
|
delegate:
|
|
(nullable id<RTCPeerConnectionDelegate>)delegate {
|
|
return [[RTCPeerConnection alloc] initWithFactory:self
|
|
configuration:configuration
|
|
constraints:constraints
|
|
delegate:delegate];
|
|
}
|
|
|
|
@end
|