e0629c045e
Make all rtc_source_test target that contains tests that are included in a test executable only be visible to the rtc_test target. Doing this exposed a couple of errors and dependency problems that were resolved. Having this could have prevented duplicated execution of tests like the case that was recently fixed by deadbeef@ in https://codereview.webrtc.org/2820263004 New targets: * //webrtc/modules/rtp_rtcp:fec_test_helper * //webrtc/modules/rtp_rtcp:mock_rtp_rtcp * //webrtc/modules/remote_bitrate_estimator:mock_remote_bitrate_observer The mock files and targets should probably be moved into webrtc/test in the future, but that's out of the scope of this CL. BUG=webrtc:5716 NOTRY=True Review-Url: https://codereview.webrtc.org/2828793003 Cr-Commit-Position: refs/heads/master@{#17863}
73 lines
2.3 KiB
Plaintext
73 lines
2.3 KiB
Plaintext
# Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license
|
|
# that can be found in the LICENSE file in the root of the source
|
|
# tree. An additional intellectual property rights grant can be found
|
|
# in the file PATENTS. All contributing project authors may
|
|
# be found in the AUTHORS file in the root of the source tree.
|
|
|
|
import("../../webrtc.gni")
|
|
|
|
rtc_static_library("bitrate_controller") {
|
|
# TODO(mbonadei): Remove (bugs.webrtc.org/6828)
|
|
# Errors on cyclic dependency with:
|
|
# congestion_controller:congestion_controller if enabled.
|
|
check_includes = false
|
|
|
|
sources = [
|
|
"bitrate_controller_impl.cc",
|
|
"bitrate_controller_impl.h",
|
|
"include/bitrate_controller.h",
|
|
"send_side_bandwidth_estimation.cc",
|
|
"send_side_bandwidth_estimation.h",
|
|
]
|
|
|
|
if (rtc_enable_bwe_test_logging) {
|
|
defines = [ "BWE_TEST_LOGGING_COMPILE_TIME_ENABLE=1" ]
|
|
} else {
|
|
defines = [ "BWE_TEST_LOGGING_COMPILE_TIME_ENABLE=0" ]
|
|
}
|
|
|
|
# TODO(jschuh): Bug 1348: fix this warning.
|
|
configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
|
|
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
|
|
deps = [
|
|
"../../base:rtc_base_approved",
|
|
"../../system_wrappers",
|
|
"../rtp_rtcp",
|
|
]
|
|
}
|
|
|
|
if (rtc_include_tests) {
|
|
rtc_source_set("bitrate_controller_unittests") {
|
|
testonly = true
|
|
|
|
# Skip restricting visibility on mobile platforms since the tests on those
|
|
# gets additional generated targets which would require many lines here to
|
|
# cover (which would be confusing to read and hard to maintain).
|
|
if (!is_android && !is_ios) {
|
|
visibility = [ "//webrtc/modules:modules_unittests" ]
|
|
}
|
|
sources = [
|
|
"bitrate_controller_unittest.cc",
|
|
"send_side_bandwidth_estimation_unittest.cc",
|
|
]
|
|
deps = [
|
|
":bitrate_controller",
|
|
"../../test:field_trial",
|
|
"../../test:test_support",
|
|
"../remote_bitrate_estimator:remote_bitrate_estimator",
|
|
"//testing/gmock",
|
|
]
|
|
if (!build_with_chromium && is_clang) {
|
|
# Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
|
|
suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
|
|
}
|
|
}
|
|
}
|