b36ee8d498
The new name, OnCompleteReports rather than OnComplete, is needed because in C++ method lookup, overriding a method hides all otherwise inherited methods with the same name, even if they have a different signature. And here, the intention is that each subclass should override one or the other of the two methods, and inherit the method it doesn't override. This cl is a prerequisite for https://codereview.webrtc.org/2567143003/, because the Chrome glue code needs to retain the stats report after the OnComplete method has returned. Currently, Chrome makes a copy of the stats mapping (which breaks when changing ValuePtr from an rtc::linked_ptr to an std::unique_ptr). After this cl, Chrome can be fixed to take ownership and no longer needs to copy anything, unblocking cl 2567143003. BUG=webrtc:6424 Review-Url: https://codereview.webrtc.org/2584553002 Cr-Commit-Position: refs/heads/master@{#15708}
65 lines
2.1 KiB
Plaintext
65 lines
2.1 KiB
Plaintext
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCPeerConnection+Private.h"
|
|
|
|
#import "NSString+StdString.h"
|
|
#import "RTCMediaStreamTrack+Private.h"
|
|
#import "RTCLegacyStatsReport+Private.h"
|
|
|
|
#include "webrtc/base/checks.h"
|
|
|
|
namespace webrtc {
|
|
|
|
class StatsObserverAdapter : public StatsObserver {
|
|
public:
|
|
StatsObserverAdapter(void (^completionHandler)
|
|
(NSArray<RTCLegacyStatsReport *> *stats)) {
|
|
completion_handler_ = completionHandler;
|
|
}
|
|
|
|
~StatsObserverAdapter() {
|
|
completion_handler_ = nil;
|
|
}
|
|
|
|
void OnCompleteReports(std::unique_ptr<StatsReports> reports) override {
|
|
RTC_DCHECK(completion_handler_);
|
|
NSMutableArray *stats = [NSMutableArray arrayWithCapacity:reports->size()];
|
|
for (const auto* report : *reports) {
|
|
RTCLegacyStatsReport *statsReport =
|
|
[[RTCLegacyStatsReport alloc] initWithNativeReport:*report];
|
|
[stats addObject:statsReport];
|
|
}
|
|
completion_handler_(stats);
|
|
completion_handler_ = nil;
|
|
}
|
|
|
|
private:
|
|
void (^completion_handler_)(NSArray<RTCLegacyStatsReport *> *stats);
|
|
};
|
|
} // namespace webrtc
|
|
|
|
@implementation RTCPeerConnection (Stats)
|
|
|
|
- (void)statsForTrack:(RTCMediaStreamTrack *)mediaStreamTrack
|
|
statsOutputLevel:(RTCStatsOutputLevel)statsOutputLevel
|
|
completionHandler:
|
|
(void (^)(NSArray<RTCLegacyStatsReport *> *stats))completionHandler {
|
|
rtc::scoped_refptr<webrtc::StatsObserverAdapter> observer(
|
|
new rtc::RefCountedObject<webrtc::StatsObserverAdapter>
|
|
(completionHandler));
|
|
webrtc::PeerConnectionInterface::StatsOutputLevel nativeOutputLevel =
|
|
[[self class] nativeStatsOutputLevelForLevel:statsOutputLevel];
|
|
self.nativePeerConnection->GetStats(
|
|
observer, mediaStreamTrack.nativeTrack, nativeOutputLevel);
|
|
}
|
|
|
|
@end
|