14d5dbe5b3
The breaking tests in Chromium have been temporarily disabled, they will be fixed and reenabled soon. Original CLs: https://codereview.webrtc.org/1748403002/, https://codereview.webrtc.org/2107253002/ and https://codereview.webrtc.org/2106103003/. TBR=solenberg@webrtc.org,tommi@webrtc.org,stefan@webrtc.org,terelius@webrtc.org,tkchin@webrtc.org BUG=webrtc:4741, webrtc:5603, chromium:609749 Review-Url: https://codereview.webrtc.org/2110113003 Cr-Commit-Position: refs/heads/master@{#13379}
87 lines
3.1 KiB
Plaintext
87 lines
3.1 KiB
Plaintext
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCPeerConnectionFactory+Private.h"
|
|
|
|
#import "NSString+StdString.h"
|
|
#import "RTCAVFoundationVideoSource+Private.h"
|
|
#import "RTCAudioTrack+Private.h"
|
|
#import "RTCMediaStream+Private.h"
|
|
#import "RTCPeerConnection+Private.h"
|
|
#import "RTCVideoSource+Private.h"
|
|
#import "RTCVideoTrack+Private.h"
|
|
|
|
@implementation RTCPeerConnectionFactory {
|
|
std::unique_ptr<rtc::Thread> _networkThread;
|
|
std::unique_ptr<rtc::Thread> _workerThread;
|
|
std::unique_ptr<rtc::Thread> _signalingThread;
|
|
}
|
|
|
|
@synthesize nativeFactory = _nativeFactory;
|
|
|
|
- (instancetype)init {
|
|
if ((self = [super init])) {
|
|
_networkThread = rtc::Thread::CreateWithSocketServer();
|
|
BOOL result = _networkThread->Start();
|
|
NSAssert(result, @"Failed to start network thread.");
|
|
|
|
_workerThread = rtc::Thread::Create();
|
|
result = _workerThread->Start();
|
|
NSAssert(result, @"Failed to start worker thread.");
|
|
|
|
_signalingThread = rtc::Thread::Create();
|
|
result = _signalingThread->Start();
|
|
NSAssert(result, @"Failed to start signaling thread.");
|
|
|
|
_nativeFactory = webrtc::CreatePeerConnectionFactory(
|
|
_networkThread.get(), _workerThread.get(), _signalingThread.get(),
|
|
nullptr, nullptr, nullptr);
|
|
NSAssert(_nativeFactory, @"Failed to initialize PeerConnectionFactory!");
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (RTCAVFoundationVideoSource *)avFoundationVideoSourceWithConstraints:
|
|
(nullable RTCMediaConstraints *)constraints {
|
|
return [[RTCAVFoundationVideoSource alloc] initWithFactory:self
|
|
constraints:constraints];
|
|
}
|
|
|
|
- (RTCAudioTrack *)audioTrackWithTrackId:(NSString *)trackId {
|
|
return [[RTCAudioTrack alloc] initWithFactory:self
|
|
trackId:trackId];
|
|
}
|
|
|
|
- (RTCVideoTrack *)videoTrackWithSource:(RTCVideoSource *)source
|
|
trackId:(NSString *)trackId {
|
|
return [[RTCVideoTrack alloc] initWithFactory:self
|
|
source:source
|
|
trackId:trackId];
|
|
}
|
|
|
|
- (RTCMediaStream *)mediaStreamWithStreamId:(NSString *)streamId {
|
|
return [[RTCMediaStream alloc] initWithFactory:self
|
|
streamId:streamId];
|
|
}
|
|
|
|
- (RTCPeerConnection *)peerConnectionWithConfiguration:
|
|
(RTCConfiguration *)configuration
|
|
constraints:
|
|
(RTCMediaConstraints *)constraints
|
|
delegate:
|
|
(nullable id<RTCPeerConnectionDelegate>)delegate {
|
|
return [[RTCPeerConnection alloc] initWithFactory:self
|
|
configuration:configuration
|
|
constraints:constraints
|
|
delegate:delegate];
|
|
}
|
|
|
|
@end
|