bca69e87de
Reason for revert: Broke downstream project. Original issue's description: > Delete cricket::VideoFrame::GetTimeStamp. > > TBR=tkchin@webrtc.org # Trivial change to VideoRendererAdapter > BUG=webrtc:5682 > > Committed: https://crrev.com/fd6c99e43137d01fa6c120f7160f7c2999d1d8a3 > Cr-Commit-Position: refs/heads/master@{#14037} TBR=perkj@webrtc.org # Skipping CQ checks because original CL landed less than 1 days ago. NOPRESUBMIT=true NOTREECHECKS=true NOTRY=true BUG=webrtc:5682 Review-Url: https://codereview.webrtc.org/2306953002 Cr-Commit-Position: refs/heads/master@{#14038}
71 lines
2.0 KiB
Plaintext
71 lines
2.0 KiB
Plaintext
/*
|
|
* Copyright 2015 The WebRTC project authors. All Rights Reserved.
|
|
*
|
|
* Use of this source code is governed by a BSD-style license
|
|
* that can be found in the LICENSE file in the root of the source
|
|
* tree. An additional intellectual property rights grant can be found
|
|
* in the file PATENTS. All contributing project authors may
|
|
* be found in the AUTHORS file in the root of the source tree.
|
|
*/
|
|
|
|
#import "RTCVideoRendererAdapter+Private.h"
|
|
|
|
#import "RTCVideoFrame+Private.h"
|
|
|
|
#include <memory>
|
|
|
|
#include "webrtc/media/engine/webrtcvideoframe.h"
|
|
|
|
namespace webrtc {
|
|
|
|
class VideoRendererAdapter
|
|
: public rtc::VideoSinkInterface<cricket::VideoFrame> {
|
|
public:
|
|
VideoRendererAdapter(RTCVideoRendererAdapter* adapter) {
|
|
adapter_ = adapter;
|
|
size_ = CGSizeZero;
|
|
}
|
|
|
|
void OnFrame(const cricket::VideoFrame& nativeVideoFrame) override {
|
|
RTCVideoFrame* videoFrame = [[RTCVideoFrame alloc]
|
|
initWithVideoBuffer:nativeVideoFrame.video_frame_buffer()
|
|
rotation:nativeVideoFrame.rotation()
|
|
timeStampNs:nativeVideoFrame.GetTimeStamp()];
|
|
CGSize current_size = (videoFrame.rotation % 180 == 0)
|
|
? CGSizeMake(videoFrame.width, videoFrame.height)
|
|
: CGSizeMake(videoFrame.height, videoFrame.width);
|
|
|
|
if (!CGSizeEqualToSize(size_, current_size)) {
|
|
size_ = current_size;
|
|
[adapter_.videoRenderer setSize:size_];
|
|
}
|
|
[adapter_.videoRenderer renderFrame:videoFrame];
|
|
}
|
|
|
|
private:
|
|
__weak RTCVideoRendererAdapter *adapter_;
|
|
CGSize size_;
|
|
};
|
|
}
|
|
|
|
@implementation RTCVideoRendererAdapter {
|
|
std::unique_ptr<webrtc::VideoRendererAdapter> _adapter;
|
|
}
|
|
|
|
@synthesize videoRenderer = _videoRenderer;
|
|
|
|
- (instancetype)initWithNativeRenderer:(id<RTCVideoRenderer>)videoRenderer {
|
|
NSParameterAssert(videoRenderer);
|
|
if (self = [super init]) {
|
|
_videoRenderer = videoRenderer;
|
|
_adapter.reset(new webrtc::VideoRendererAdapter(self));
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (rtc::VideoSinkInterface<cricket::VideoFrame> *)nativeVideoRenderer {
|
|
return _adapter.get();
|
|
}
|
|
|
|
@end
|